Rust を始める準備

Rust コードの実行を開始する前に、いくつか初期化を行う必要があります。

/**
 * This is a generic entry point for an image. It carries out the
 * operations required to prepare the loaded image to be run.
 * Specifically, it
 *
 * - sets up the MMU with an identity map of virtual to physical
 *   addresses, and enables caching
 * - enables floating point
 * - zeroes the bss section using registers x25 and above
 * - prepares the stack, pointing to a section within the image
 * - sets up the exception vector
 * - branches to the Rust `main` function
 *
 * It preserves x0-x3 for the Rust entry point, as these may contain
 * boot parameters.
 */
.section .init.entry, "ax"
.global entry
entry:
    /*
     * Load and apply the memory management configuration, ready to
     * enable MMU and caches.
     */
    adrp x30, idmap
    msr ttbr0_el1, x30

    mov_i x30, .Lmairval
    msr mair_el1, x30

    mov_i x30, .Ltcrval
    /* Copy the supported PA range into TCR_EL1.IPS. */
    mrs x29, id_aa64mmfr0_el1
    bfi x30, x29, #32, #4

    msr tcr_el1, x30

    mov_i x30, .Lsctlrval

    /*
     * Ensure everything before this point has completed, then
     * invalidate any potentially stale local TLB entries before they
     * start being used.
     */
    isb
    tlbi vmalle1
    ic iallu
    dsb nsh
    isb

    /*
     * Configure sctlr_el1 to enable MMU and cache and don't proceed
     * until this has completed.
     */
    msr sctlr_el1, x30
    isb

    /* Disable trapping floating point access in EL1. */
    mrs x30, cpacr_el1
    orr x30, x30, #(0x3 << 20)
    msr cpacr_el1, x30
    isb

    /* Zero out the bss section. */
    adr_l x29, bss_begin
    adr_l x30, bss_end
0:  cmp x29, x30
    b.hs 1f
    stp xzr, xzr, [x29], #16
    b 0b

1:  /* Prepare the stack. */
    adr_l x30, boot_stack_end
    mov sp, x30

    /* Set up exception vector. */
    adr x30, vector_table_el1
    msr vbar_el1, x30

    /* Call into Rust code. */
    bl main

    /* Loop forever waiting for interrupts. */
2:  wfi
    b 2b

このコードは src/bare-metal/aps/examples/src/entry.S にあります。これを詳細に 理解する必要はありませんが、要点は、Rust がシステムに期待する条件を満たすために、 何らかの低レベルなセットアップが必要だということです。

  • これは C の場合と同じです。つまり、プロセッサ状態を初期化し、BSS をゼロクリアし、 スタックポインタを設定します。
    • BSS（歴史的な理由による名称で、block starting symbol）は、 ゼロで初期化される静的に確保された変数を含むオブジェクトファイルの一部です。 これらはゼロに領域を使って無駄にしないよう、イメージには含まれません。 コンパイラは、ローダーがそれらをゼロクリアしてくれることを前提にしています。
  • メモリがどのように初期化され、イメージがどのようにロードされるかによっては、BSS は すでにゼロクリアされている場合もありますが、確実を期すためにこちらでゼロクリアします。
  • メモリの読み書きを行う前に、MMU とキャッシュを有効にする必要があります。そうしないと、 次の問題が起こります。
    • 非アラインアクセスでフォールトが発生します。Rust コードは、コンパイラが 非アラインアクセスを生成しないよう +strict-align が設定された aarch64-unknown-none ターゲット向けにビルドしているため、このケースでは 問題ないはずですが、一般には必ずしもそうとは限りません。
    • VM 上で動作している場合、キャッシュコヒーレンシの問題につながる可能性があります。 問題は、VM はキャッシュを無効にした状態でメモリに直接アクセスしている一方で、 ホストは同じメモリに対するキャッシュ可能な別名を持っていることです。ホストが 明示的にそのメモリへアクセスしなくても、投機的アクセスによってキャッシュフィルが 発生し、その後キャッシュがクリーンされたり VM がキャッシュを有効にしたりすると、 どちらか一方の変更が失われてしまいます。（キャッシュは VA や IPA ではなく、 物理アドレスをキーにしています。）
  • 単純化のため、先頭の 1 GiB のアドレス空間をデバイス用に、その次の 1 GiB を DRAM 用に、 さらにその上位の別の 1 GiB を追加のデバイス用に恒等マップする、ハードコードされた ページテーブル（idmap.S を参照）をそのまま使用します。これは QEMU が使用する メモリレイアウトと一致しています。
  • 例外ベクタ（vbar_el1）も設定します。これについては後でもう少し詳しく見ます。
  • この午後のすべての例では、例外レベル 1（EL1）で実行することを前提としています。 別の例外レベルで実行する必要がある場合は、それに応じて entry.S を変更する必要があります。